とりあえず完成

当初の目的である、永字が完成しました。まだまだ左右の太さ、バランスともに駄目駄目ですが、これから何文字か作って行く過程でその辺は自分で解決して行く予定です。（公開はおそらくしません。）

永字の像とソースだけは公開しておきます。

%%   soucho font sample 
%%   2007.9.25  Kazz Aoshima

mode_setup;

em#:=16pt#;
cap#:=20pt#;
s#:=1pt#;

define_pixels(em,cap,s);

beginchar("a",em#,cap#,0);

	pickup pencircle xscaled 0.01pt yscaled 1pt   ;

	z1=(0.4w,0.9h);
	z2=(0.55w,0.85h);
	penpos1(1.0pt,135);
	penpos2(0.8pt,55);;
	
	penstroke z1e..z2e;
	
	x3=0.25w; x5=0.5w; x4=1/2(x3+x5);
	y3=y4=y5=0.75h;
	
	penpos3(1.5pt,145);
	penpos4(0.8pt,100);
	penpos5(1.5pt,115);
	y5l := 1/3[y5l, y5];
	
	penstroke z3e..z4e..z5e;
	
	x6=0.1w; x8=0.45w; 
	x7=1/2(x6+x8);
	y6=y7=y8=0.6h;
	
	penpos6(1.8pt,145);
	penpos7(0.8pt,100);
	penpos8(1.5pt,115);
	y8l := 1/3[y8l, y8];
	
	penstroke z6e..z7e..z8e;



	pickup pencircle xscaled 1pt yscaled 0.01pt   ;

	x9=x10=x11=0.5w;
	y9=0.78h; y11=0.1h;
	y10=1/2(y9+y11);
	
	penpos9(1.3pt,170);
	penpos10(0.8pt,180);
	penpos11(1pt,190);

	penstroke z9e..z10e..z11e;

	pickup pencircle xscaled 0.01pt yscaled 1pt   ;

	z12=(0.5w,0.1h);
	z13=(0.3w,0.2h);
	penpos12(1.1pt,20);
	penpos13(0.5pt,130);
	
	penstroke z12e..z13e;
	
	z14=(0.45w,0.6h);
	z16=(0.1w,0.15h);
	
	penpos14(1.5pt,120);
	penpos16(1.0pt,200);
	y16l := 1/2[y16l, y16];

	x15=1/2(x14+x16); y15=1/2(y14+y16)-0.05h;
	penpos15(1.0pt,100);
	y15l := 1.5[y15, y15l]; 
	y15r := 0.5[y15r, y15]; 
		
	penstroke z14e..z15e..z16e;


	
	z17=(0.82w,0.72h);
	z19=(0.58w,0.6h);
	
	penpos17(1.2pt,135);
	penpos19(1.0pt,180);
	y19l := 1/2[y19l, y19];

	x18=1/2(x17+x19); y18=1/2(y17+y19);
	y18l := 1[y18, y18l]; 
	y18r := 0.5[y18r, y18]; 
	penpos18(0.8pt,75);
		
	penstroke z17e..z18e..z19e;
	
	
	z20=(0.55w,0.58h);
	z22=(0.92w,0.1h);
	
	penpos20(1.2pt,80);
	penpos22(1.0pt,-10);
	y22l := 1/2[y22l, y22];

	x21=1/2(x20+x22)+0.05w; y21=1/2(y20+y22)-0.15h;
	penpos21(1.2pt,60);
			
	penstroke z20e--z21e--z22e;
	
	

   labels(range 1 thru 30);
   
endchar;

bye;